@verb #3482:"b" none none none rdo #9452
@program #3482:"b" none none none
dude = $lord_database:authenticate(player)
if (typeof(dude) == WAIF)
  player:tell("  The Legend of the Red Dragon - Weapons List")
  $lord_database:tell_separator()
  player:tell("      Weapons                           Price")
  for weapon in ($lord_database.weapon_stats)
    player:tell("  " + $string_utils:right(tostr(weapon in $lord_database.weapon_stats), 2) + ". " + $string_utils:left(weapon[1], 30, ".") + $string_utils:right($string_utils:group_number(weapon[2]), 12, "."))
  endfor
  player:tell("  (Gold: " + tostr(dude->gold_hand) + ")  (0 to exit)")
  weapon_index = $command_utils:read("the number of a weapon")
  weapon_index = toint(weapon_index)
  if (weapon_index >= 1 && weapon_index <= length($lord_database.weapon_stats))
    weapon = $lord_database.weapon_stats[weapon_index]
    player:tell("  \"Hmmm, I will sell you my FAVORITE " + weapon[1] + " for " + $string_utils:group_number(weapon[2]) + " gold!\"")
    player:tell()
    player:tell("  Buy it?  [N]")
    answer = $command_utils:read()
    if (answer == "y")
      if (dude->gold_hand < weapon[2])
        player:tell("  \"You stupid fool!  You don't have that much gold!  I knew you were up to")
        player:tell("  good the moment I saw you!\"")
      elseif (dude->weapon_index != 0)
        player:tell("  \"You fool!  You already have a weapon, and you can't carry two!\"")
        player:tell("  You realize he is right.")
      else
        player:tell("  \"Great!\"  The fat man takes your money, and gives you the weapon.")
        dude->gold_hand = $lord_database:intsub(dude->gold_hand, weapon[2])
        dude->strength = dude->strength + weapon[3]
        dude->weapon_index = weapon in $lord_database.weapon_stats
        dude->weapon_name = weapon[1]
      endif
    else
      player:tell("  \"Fine...  You will come back...\" the man grunts.")
    endif
  endif
  player:tell(this.menu_msg)
endif
"Last modified by Crono (#9452) on Sun Sep  8 19:33:49 2002 MDT."
.