tfig.gp - cngf-pf-exp1 - experiments for first paper with continuum granular model
HTML git clone git://src.adamsgaard.dk/manus_continuum_granular1_exp
DIR Log
DIR Files
DIR Refs
DIR Submodules
DIR README
DIR LICENSE
---
tfig.gp (1291B)
---
1 #!/usr/bin/env gnuplot
2 reset
3
4 set terminal pdfcairo color size 7.5 cm, 10.5 cm
5
6 set multiplot layout 4,1 \
7 margins 0.19,0.72,0.10,0.98 \
8 spacing 0.00,0.03
9
10 set key top right samplen 1.0 font ",10"
11 unset xlabel
12 set xtics format ""
13 set yrange [0:320]
14 set ylabel "{/:Normal [kPa]}"
15 set ytics 100
16
17 set label "{/:Bold e}" at graph 0.05,0.9
18
19 plot \
20 "timeseries.txt" u ($0/1008*7):($2/1000) w l lw 2 lc "black" t "effective normal stress", \
21 "" u ($0/1008*7):($3/1000) w l lw 2 lt 3 dt "-" t "water pressure"
22
23 unset label
24 set label "{/:Bold f}" at graph 0.05,0.9
25 unset ylabel
26 unset ytics
27 set yrange [0:80]
28 set y2range [0:80]
29 set y2tics 20
30 set y2label "{/:Normal Shear stress [kPa]}"
31 plot "" u ($0/1008*7):($4*$2/1000) w l lw 2 lt 1 t ""
32
33 unset label
34 set label "{/:Bold g}" at graph 0.05,0.9
35 unset y2label
36 unset y2tics
37 set ytics 0.5
38 set yrange [2.5:0.0]
39 set ylabel "{/:Normal Depth of max. strain rate [m]}"
40 plot "max_strainrate_depth.txt" u ($0/1008*7):(8.0 - $1) w l lw 2 lt 4 t ""
41
42 unset label
43 set label "{/:Bold h}" at graph 0.05,0.9
44 unset ylabel
45 unset ytics
46 set yrange [0.0:1e-4]
47 set y2range [0.0:1e-4]
48 set y2tics 3e-5
49 set y2label "{/:Normal Specific sediment flux [m^2/s]}"
50 set xtics 1 format "%g"
51 set xlabel "{/:Normal Time [d]}"
52 plot "sediment_flux.txt" u ($0/1008*7):1 w l lw 2 lt 6 t ""