tcommon_definitions.mac - pism - [fork] customized build of PISM, the parallel ice sheet model (tillflux branch)
HTML git clone git://src.adamsgaard.dk/pism
DIR Log
DIR Files
DIR Refs
DIR LICENSE
---
tcommon_definitions.mac (1586B)
---
1 display2d : true $
2 linel : 100 $
3 leftjust : true $
4
5 unorder()$
6 orderless(A, B, C)$
7
8 set_tex_environment_default("@f[", "@f]~%")$
9
10 texput_list(l) := map(lambda([x], apply(texput, x)), l)$
11
12 texput_list([
13 [ice_heat_capacity, "c_{pI}"],
14 [ocean_heat_capacity, "c_{pW}"],
15 [S_B, "S^B"],
16 [S_W, "S^W"],
17 [gamma_s, "\\gamma_S"],
18 [gamma_t, "\\gamma_T"],
19 [T_S, "T^S"],
20 [Theta_W, "\\Theta^W"],
21 [nounify(T_B), "T^B"],
22 [nounify(Theta_B), "\\Theta^B"],
23 [grad_T, "\\nabla T"],
24 [melt_rate, "w_b"],
25 [ocean_density, "\\rho_W"],
26 [ice_density, "\\rho_I"],
27 [ice_thickness, "h"],
28 [ice_thermal_diffusivity, "\\kappa"]
29 ])$
30
31 /* $\dot h$ is defined to me minus the melt rate */
32 h_dot : - melt_rate$
33
34 delta_T : T_S - T_B$
35
36 /* heat flux at the ice-brine interface */
37 Qti(grad_T) := ice_density * ice_heat_capacity * ice_thermal_diffusivity * grad_T$
38
39 /* heat flux into the ocean (due to melting) */
40 Qtb : ice_density * h_dot * L$
41
42 /* heat flux into the ocean mixed layer */
43 Qtm : ocean_density * ocean_heat_capacity * gamma_t * (Theta_B - Theta_W)$
44
45 /* salinity in the ice */
46 S_I : 0$
47
48 /* salinity flux into the ice */
49 Qsi : 0$
50
51 /* salt flux at the base (10) */
52 Qsb : ice_density * h_dot * (S_B - S_I)$
53
54 /* salinity flux into the mixed ocean layer */
55 Qsm : ocean_density * gamma_s * (S_B - S_W)$
56
57 /* parameterization of the melting point temperature */
58 T_B(S_B, ice_thickness) := a[1] + a[0] * S_B + a[2] * ice_thickness$
59
60 /* parameterization of the potential temperature corresponding to the
61 melting point */
62 Theta_B(S_B, ice_thickness) := b[1] + b[0] * S_B + b[2] * ice_thickness$