media-video/jellyfin-mpv-shim: Add 2.2.0 - parlay - yet another gentoo overlay
HTML git clone https://git.parazyd.org/parlay
DIR Log
DIR Files
DIR Refs
DIR README
---
DIR commit 1529f8a57b6007d0f822abf68563f28fadb5d671
DIR parent 4cc64cf61d955ff8843349e0bcf3dcd699a68430
HTML Author: parazyd <parazyd@dyne.org>
Date: Fri, 21 Oct 2022 22:24:51 +0200
media-video/jellyfin-mpv-shim: Add 2.2.0
Diffstat:
A media-video/jellyfin-mpv-shim/Mani… | 1 +
A media-video/jellyfin-mpv-shim/jell… | 71 +++++++++++++++++++++++++++++++
A media-video/jellyfin-mpv-shim/meta… | 12 ++++++++++++
3 files changed, 84 insertions(+), 0 deletions(-)
---
DIR diff --git a/media-video/jellyfin-mpv-shim/Manifest b/media-video/jellyfin-mpv-shim/Manifest
@@ -0,0 +1 @@
+DIST jellyfin-mpv-shim-2.2.0.tar.gz 498494 BLAKE2B 48109d9b6d75086ff9c256a6898cb4b55c9e6825c625faffe0abde4340839088e4f1db7d8377d08b8f7ac2e3165a18b462c0fa282fb6326ce2aa7fdcb53c3086 SHA512 9466289c914d23313b16253cad9d904005e21f42b3d45740472bb253431d339522e672505f29db0bda6dba8fc916d7fc797bcc28ab7cc63f40bd7fb3edfcc24b
DIR diff --git a/media-video/jellyfin-mpv-shim/jellyfin-mpv-shim-2.2.0.ebuild b/media-video/jellyfin-mpv-shim/jellyfin-mpv-shim-2.2.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+inherit distutils-r1 desktop
+
+DESCRIPTION="MPV Cast Client for Jellyfin"
+HOMEPAGE="https://github.com/jellyfin/jellyfin-mpv-shim"
+SRC_URI="https://github.com/jellyfin/jellyfin-mpv-shim/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="display-mirroring shaders +systray"
+
+DEPEND="
+ media-video/mpv[libmpv]
+ >=dev-lang/python-3.6[tk]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/python-mpv[${PYTHON_USEDEP}]
+ >=dev-python/python-mpv-jsonipc-1.1.9[${PYTHON_USEDEP}]
+ >=dev-python/jellyfin-apiclient-python-1.8.1[${PYTHON_USEDEP}]
+ systray? (
+ dev-python/pystray[${PYTHON_USEDEP}]
+ dev-python/pillow[${PYTHON_USEDEP}]
+ )
+ display-mirroring? (
+ dev-python/jinja[${PYTHON_USEDEP}]
+ dev-python/pywebview[${PYTHON_USEDEP}]
+ )
+ shaders? ( media-video/jellyfin-mpv-shim-default-shader-pack )
+"
+RDEPEND="${DEPEND}"
+BDEPEND=""
+
+shaders_symlink() {
+ ln -sv "/usr/share/jellyfin-mpv-shim-default-shader-pack" \
+ "${ED}/$(python_get_sitedir)/jellyfin_mpv_shim/default_shader_pack" || die
+}
+
+src_prepare() {
+ #move integration dir out of the way
+ #so setuptools doesn't install it
+ mv ${S}/jellyfin_mpv_shim/integration ${WORKDIR}
+
+ distutils-r1_src_prepare
+}
+
+src_install() {
+ distutils-r1_src_install
+
+ # Setup symlink to mpv-shim-default-shaders
+ if use shaders; then
+ python_foreach_impl shaders_symlink
+ fi
+
+ #Install desktop stuff
+ pushd ${WORKDIR}/integration
+ domenu com.github.iwalton3.jellyfin-mpv-shim.desktop
+ for icon in *.png; do
+ local size=${icon#jellyfin-*}
+ size=${size%*.png}
+ newicon --size ${size} ${icon} com.github.iwalton3.jellyfin-mpv-shim.png
+ done
+ insinto /usr/share/metainfo/
+ doins com.github.iwalton3.jellyfin-mpv-shim.appdata.xml
+ popd
+}
DIR diff --git a/media-video/jellyfin-mpv-shim/metadata.xml b/media-video/jellyfin-mpv-shim/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person">
+ <email>parazyd@dyne.org</email>
+ </maintainer>
+ <use>
+ <flag name="display-mirroring">Enable display-mirroring</flag>
+ <flag name="systray">Enable systray via <pkg>dev-python/pystray</pkg></flag>
+ <flag name="shaders">Install the default shader pack</flag>
+ </use>
+</pkgmetadata>