*********************    ***********************  
      ******      .                              .  ******
     ****     .  .   .  Init & Exit code     .   "     **** 
    ***   '         .   """"""""""""""""             .   *** 
    **  .  .    . .                        .  "  . .      ** 
    **       "       written in a hurry for     . .       ** 
    ***  .  :   . .  """"""""""""""""""""""        .     *** 
     ****          #Amycoders' starfield compo      by **** 
      ******    .  """""""""""""""""""""""""""      morbid  
        *********************    ***********************   
                




        bsr     CloseWB         ; Flush view and disable multitasking
        bsr     OpenScreen      ; Set pointers and sync

        jsr     Starfield_init  ;Init starfield
        
**
************************************************************
************************************************************
**
**                    >>> M A I N <<<
**



        


Main    btst    #6,$bfe001
        beq     Exit
        
        
        
************************************************************


        bsr     DisplayScreen
        move	#$040,$dff180
        jsr     Starfield       ;call starfield (a0=Bitplane)
        move	#$000,$dff180
        bra     Main




        
**
************************************************************
**
**      Flush view & disable system
**


CloseWB

        movea.l 4.w,a6          ; exec base
        jsr     -132(a6)        ; Forbid
        jsr     -120(a6)        ; Disable
        lea     GfxName(pc),a1  ; graphics.library
        moveq   #0,d0           ; whatever verision
        jsr     -552(a6)        ; open it !
        move.l  d0,GfxBase      ; store gfxbase
        movea.l d0,a6           ; gfxbase in a6
        move.l  $22(a6),OldView ; store system view
        move.l  $26(a6),OldCop  ; store system copper
        sub.l   a1,a1
        jsr     -222(a6)        ; flush view (LoadView)
        jsr     -270(a6)        ; WaitTOF
        jsr     -270(a6)        ; twice for interlaced views
        move.w  $dff002,OldDMAcon   ; store old dma control register
        ori.w   #$8000,OldDMAcon  ; set bit #15
        move.w  #$7fff,$dff096
        move.w  #$8380,$dff096
        rts
        
        
GfxName dc.b 'graphics.library',0
        even
GfxBase dc.l 0
OldView dc.l 0
OldCop  dc.l 0
OldDMAcon dc.w 0

        cnop 0,4

**
*************************************************************
**
**      Display Screen
**

DisplayScreen

        movem.l d0-d1,-(sp)
        move.b  $bfe801,d0
.wait   cmp.b   $bfe801,d0
        beq.b   .wait
        
        move.l  screen_logical(pc),d0
        move.l  screen_physical(pc),screen_logical
        move.l  d0,screen_physical

        lea     copper_bpl,a0
        move.w  d0,6(a0)                ; lower part of bpl address
        swap    d0
        move.w  d0,2(a0)                ; higher word

        movea.l screen_logical(pc),a0   
        moveq   #0,d0
        move.l  #(320/32)*256-1,d1
.clear  move.l  d0,(a0)+                ; clear logical screen
        dbf     d1,.clear
        lea     -(320/8)*256(a0),a0     
        
        movem.l (sp)+,d0-d1
        rts


screen_physical dc.l 0
screen_logical dc.l 0

        
**
*************************************************************
**
**      Open Screen
**

OpenScreen
        
        lea     $dff000,a5
        move.l  #Copper,$80(a5)
        
        move.w  #$2c81,$08e(a5)         ; display window start pos
        move.w  #$2cc1,$090(a5)         ; display window stop pos
        move.w  #$0038,$092(a5)         ; data fetch start pos
        move.w  #$00d0,$094(a5)         ; data fetch stop pos

        move.l  #ScreenA,screen_logical
        move.l  #ScreenB,screen_physical
        bsr     DisplayScreen
        
        rts
        
**
**************************************************************
**
**      Open WB 
**

Exit
        lea     $dff000,a5
        move.w  #$7fff,$96(a5)          ; clear dmacon
        move.w  OldDMAcon(pc),$96(a5)   ; set old bits
        move.l  GfxBase(pc),a6          ; gfxbase in a6
        move.l  OldCop(pc),$80(a5)      ; restart old copperlist
        move.l  OldView(pc),a1
        jsr     -222(a6)                ; Load system view
        
        move.l  a6,a1
        move.l  4.w,a6
        jsr     -414(a6)                ; close graphics.library
        jsr     -126(a6)                ; Enable
        jsr     -138(a6)                ; Permit
        
        rts
        
        

************************************************************************

        section screens,bss_c
        
ScreenA ds.b (320*256)/8
ScreenB ds.b (320*256)/8

************************************************************************

        section copperlist,data_c

        
Copper  dc.l $01001000  ; bplcon0
        dc.l $01080000  ; bpl1mod
        dc.l $010a0000  ; bpl2mod
        dc.l $01800000  ; colour 0 = black
        dc.l $01820fff  ; colour 1 = white
                
copper_bpl
        dc.l $00e00000  ; bpl1pth
        dc.l $00e20000  ; bpl1ptl


        dc.l $fffffffe


**************************************************************************
**************************************************************************
**
**
**  Your starfield code starts here
**
**  Azure
**
**  Done 15.6.97
**
**  64 bytes
**
**************************************************************************
**************************************************************************


        section code,code       ;put your code here

*********************************************
** Do all initialisations here
*********************************************
SpeedOfStars=6
NoFlicker=0	;set this to one to avoid that flickering star
		;(2 bytes longer)
LimitZ=0	;set this to one to make the starfield looking a bit
		;better by limiting Z. (4 bytes longer)

Starfield_init:
a


b
        rts


*********************************************
** This routine is called once a frame
**
** The destination Bitplane is given in a0
*********************************************

Starfield:
c
	lsr.w	#7,d6

	IFEQ	NoFlicker
	
	lea	StarBuffer+6,a1

	ELSE

	lea	starbuffer,a1
	bra.s	.lop1
	ENDC
				;this trick causes one star to
				;"teleport" around..  
.newpos
	ror.l	#7,d7		;random number generator 
	add.w	d6,d7		
	
;	move	d7,-(a1)	;y-pos now random number
;	move	d2,-(a1)	;x-pos now former y-pos
;	move	d1,-(a1)	;z-pos now former x-pos
				;using this trick the random-numbers
				;are cycles through the coordinate
				;parts	
	movem.w	d1/d2/d7,-(a1)
.lop1
	IFNE	LimitZ
	or.w	#%0111110000000000,(a1)
	ENDC
	addq.w	#SpeedOfStars,(a1)
	movem.w	(a1)+,d0-d2	;z x y (movem doesnt alter flags)
	bpl.s	.newpos		;illegal position (behind viewer or at z=0)

	divs.w	d0,d1
	divs.w	d0,d2		;perspective
				;higher words have been cleared in the 
				;previous run	
	add.w	#160,d1
	add.w	#128,d2
	ext.l	d1
	mulu.w	#40,d2		;clears upper word of d1/d2 for next
				;run

	cmp.w	#320,d1
	bcc.s	.newpos
	cmp.w	#256*40,d2
	bcc.s	.newpos

	bfset	(a0,d2){d1:1}	;d2 is row offset
				;d1 is x-pos
.out	
	dbf	d6,.lop1	
d
        rts

	printt "Length of code:"
	printv ((b-a)+(d-c))

        section bss,bss         ;put your tables heres

StarBuffer:

	ds.w	512*3
	



.