PHXASS	=	0

	IFNE PHXASS

	machine	68020

	ENDIF

        *********************    ***********************  
      ******      .                              .  ******
     ****     .  .   .  Init & Exit code     .   "     **** 
    ***   '         .   """"""""""""""""             .   *** 
    **  .  .    . .                        .  "  . .      ** 
    **       "       written in a hurry for     . .       ** 
    ***  .  :   . .  """"""""""""""""""""""        .     *** 
     ****          #Amycoders' starfield compo      by **** 
      ******    .  """""""""""""""""""""""""""      morbid  
        *********************    ***********************   

        bsr.b     CloseWB         ; Flush view and disable multitasking
        bsr.w     OpenScreen      ; Set pointers and sync

        jsr     Starfield_init  ;Init starfield
        
**
************************************************************
************************************************************
**
**                    >>> M A I N <<<
**



        


Main    btst    #6,$bfe001
        beq.w     Exit
        
        
        
************************************************************


        bsr.w     DisplayScreen
        jsr     Starfield       ;call starfield (a0=Bitplane)
        bra.b     Main




        
**
************************************************************
**
**      Flush view & disable system
**


CloseWB

        movea.l 4.w,a6          ; exec base
        jsr     -132(a6)        ; Forbid
        jsr     -120(a6)        ; Disable
        lea     GfxName(pc),a1  ; graphics.library
        moveq   #0,d0           ; whatever verision
        jsr     -552(a6)        ; open it !
        move.l  d0,GfxBase      ; store gfxbase
        movea.l d0,a6           ; gfxbase in a6
        move.l  $22(a6),OldView ; store system view
        move.l  $26(a6),OldCop  ; store system copper
        sub.l   a1,a1
        jsr     -222(a6)        ; flush view (LoadView)
        jsr     -270(a6)        ; WaitTOF
        jsr     -270(a6)        ; twice for interlaced views
        move.w  $dff002,OldDMAcon   ; store old dma control register
        ori.w   #$8000,OldDMAcon  ; set bit #15
        move.w  #$7fff,$dff096
        move.w  #$8380,$dff096
        rts
        
        
GfxName dc.b 'graphics.library',0
        even
GfxBase dc.l 0
OldView dc.l 0
OldCop  dc.l 0
OldDMAcon dc.w 0

        cnop 0,4

**
*************************************************************
**
**      Display Screen
**

DisplayScreen

        movem.l d0-d1,-(sp)
        move.b  $bfe801,d0
.wait   cmp.b   $bfe801,d0
        beq.b   .wait
        
        move.l  screen_logical(pc),d0
        move.l  screen_physical(pc),screen_logical
        move.l  d0,screen_physical

        lea     copper_bpl,a0
        move.w  d0,6(a0)                ; lower part of bpl address
        swap    d0
        move.w  d0,2(a0)                ; higher word

        movea.l screen_logical(pc),a0   
        moveq   #0,d0
        move.l  #(320/32)*256-1,d1
.clear  move.l  d0,(a0)+                ; clear logical screen
        dbf     d1,.clear
        lea     -(320/8)*256(a0),a0     
        
        movem.l (sp)+,d0-d1
        rts


screen_physical dc.l 0
screen_logical dc.l 0

        
**
*************************************************************
**
**      Open Screen
**

OpenScreen
        
        lea     $dff000,a5
        move.l  #Copper,$80(a5)
        
        move.w  #$2c81,$08e(a5)         ; display window start pos
        move.w  #$2cc1,$090(a5)         ; display window stop pos
        move.w  #$0038,$092(a5)         ; data fetch start pos
        move.w  #$00d0,$094(a5)         ; data fetch stop pos

        move.l  #ScreenA,screen_logical
        move.l  #ScreenB,screen_physical
        bsr.w     DisplayScreen
        
        rts
        
**
**************************************************************
**
**      Open WB 
**

Exit
        lea     $dff000,a5
        move.w  #$7fff,$96(a5)          ; clear dmacon
        move.w  OldDMAcon(pc),$96(a5)   ; set old bits
        move.l  GfxBase(pc),a6          ; gfxbase in a6
        move.l  OldCop(pc),$80(a5)      ; restart old copperlist
        move.l  OldView(pc),a1
        jsr     -222(a6)                ; Load system view
        
        move.l  a6,a1
        move.l  4.w,a6
        jsr     -414(a6)                ; close graphics.library
        jsr     -126(a6)                ; Enable
        jsr     -138(a6)                ; Permit
        
        rts
        
        

************************************************************************

        section screens,bss_c
        
ScreenA ds.b (320*256)/8
ScreenB ds.b (320*256)/8

************************************************************************

        section copperlist,data_c

        
Copper  dc.l $01001000  ; bplcon0
        dc.l $01080000  ; bpl1mod
        dc.l $010a0000  ; bpl2mod
        dc.l $01800000  ; colour 0 = black
        dc.l $01820fff  ; colour 1 = white
                
copper_bpl
        dc.l $00e00000  ; bpl1pth
        dc.l $00e20000  ; bpl1ptl
 

        dc.l $fffffffe


**************************************************************************
**************************************************************************
**
**
**  Your starfield code starts here
**
**
**************************************************************************
**************************************************************************


        section code,code       ;put your code here

*********************************************
** Do all initialisations here
*********************************************

Starfield_init:
a
b
        rts

*********************************************
** This routine is called once a frame
**
** The destination Bitplane is given in a0
*********************************************

Starfield:

* * * * * * * * * * * * * * * * * * * * * * * * * * * *
 * 64 byte starfield routine.                        *
 *                                                   *
 * By: ChiP / PowerLine (Jesper Svennevid)           *
 *                                                   *
 * Email: chip@beer.com                              *
 *                                                   *
 * Copyright C 1997 Jesper Svennevid                 *
* * * * * * * * * * * * * * * * * * * * * * * * * * * * 
c

	lea.l	(-512*3*2)-32(sp),a1

	moveq.l	#-128,d3			;use as temporary(size gain)
	move.w	#160,d4

.CalcAndPlot

	movem.w	(a1),d0-d2			;read coordinates

	subq.w	#7,d2				;decrease Z
	bgt.b	.NotRandom			;check if z<0

	* randomize x,y,z

	eor.l	d6,(a1)
	eor.w	d2,(a1)
	add.w	d2,d6
	add.w	d6,d2

.NotRandom

	addq.l	#4,a1

	move.w	d2,(a1)+

	divs.w	d2,d0				;projection
	divs.w	d2,d1

	* perform centering and clipping

	cmp.w	d3,d1				;check if y<=-128
	ble.b	.NoPoint			;clip higher y
	add.w	d3,d1				;add 128 to y (y origo)
	bgt.b	.NoPoint			;clip lower y

	cmp.w	d4,d0				;check if x>=320
	bge.b	.NoPoint			;clip higher x
	add.w	d4,d0				;add 160 to x (x origo)
	blt.b	.NoPoint			;clip lower x

	* plot pixel

	muls.w	#-320,d1			;mul y and correct sign
	add.w	d0,d1				;add x to y
	bfset	(a0){d1:1}			;plot pixel

.NoPoint

	sub.w	d3,d7
	bvc.b	.CalcAndPlot

d
        rts

	IFEQ PHXASS

	printt "Length of code:"
	printv ((b-a)+(d-c))

	ENDIF

        section bss,bss         ;put your tables heres
.